Дайте пожалуйста клео использование наркотиков, которое на скриншоте, только на букву C, либо же измените кнопку активации в коде клео

[Bebra_Best]

Дайте пожалуйста индентичное клео, которое ниже на скриншотах, только на букву C

Или измените пожалуйста в этом коде клео, которое вставлю ниже на букву C, так же само клео прикреплю

{$CLEO}
{$INCLUDE SF}
0000:
thread 'bladee'

repeat
  wait 0
until SAMP.Available()

if 8AAB: not file_exists 'CLEO\sbiv.ini'
then 0AF1: write_int 0 to_ini_file 'CLEO\sbiv.ini' section "Drugtimer for Evolve RP" key 'sbiv'
end

0AF0: 8@ = get_int_from_ini_file 'CLEO\sbiv.ini' section "Drugtimer for Evolve RP" key 'sbiv'
if 8@ >= 1
then
    8@ = true
    13@ = true
else 8@ = false
end
0AF1: write_int 8@ to_ini_file 'CLEO\sbiv.ini' section "Drugtimer for Evolve RP" key 'sbiv'

0B34: samp register_client_command 'tsbiv' to_label @CMD_SBIV
0B34: samp register_client_command 'tinfo' to_label @CMD_INFO
0C74: 1 = create_timer_interval 1000 on_label @TIMER
0C78: set_timer 1 active false

repeat
  wait 0
until 02CB: actor $PLAYER_ACTOR bounding_sphere_visible
0BE3: raknet setup_incoming_rpc_hook @RPC_INCOMING

:START
while 82CB: not actor $PLAYER_ACTOR bounding_sphere_visible
  wait 0
end
if 13@ == true
then
    SAMP.ReadSAMPMemory(19@, 0x16FA0, 2)
    SAMP.WriteSAMPMemory(0x16FA0, 50064, 2)
    13@--
end
0A8D: 9@ = read_memory 12030944 size 4 virtual_protect true
if 9@ == 569.0
then
    0C48: samp textdraw 10 create 'Use!' pos 610.0 65.5
    10@ = 1
else
    0C48: samp textdraw 10 create 'Use!' pos 610.0 75.8
    10@ = 0
end                      
0C52: samp textdraw 10 set_letter_size 0.225 1.1 color 0xFFFFFFFF
0C4D: samp textdraw 10 set_shadow 1 color 0xFF000000
0C4E: samp textdraw 10 set_outline 1 color 0xFF000000
0B34: samp register_client_command 'tres' to_label @CMD_RESET

while true
  wait 0
    gosub @TEXTDRAW_POS
    if and
      0ADC: 'X'
      not Actor.Dead($PLAYER_ACTOR)
      not SAMP.IsCursorActive()
      8C79: not    is_timer 1 active
      1@ == 0
      22@ > 0
    then
        12@ = Actor.Health($PLAYER_ACTOR)
        17@ = 160
        0062: 17@ -= 12@
        17@ /= 10
        if 17@ > 0
        then say '/usedrugs %d' 17@
        else say '/usedrugs 1'
        end
    end
       
    12@ = SAMP.GetGamestate()
    if 12@ == GAMESTATE_DISCONNECTED
    then
        0C78: set_timer 1 active false
        SAMP.UnregisterClientCommand('tres')
        repeat
          wait 0
            12@ = SAMP.GetGamestate()
            gosub @TEXTDRAW_POS
        until 12@ == GAMESTATE_CONNECTED
        jump @START
    end
   
    if and
      0C79: is_timer 1 active
      12@ == GAMESTATE_CONNECTED
    then
        if or
          Actor.Dead($PLAYER_ACTOR)
          22@ <= 0
        then
            repeat
              wait 0
                gosub @TEXTDRAW_POS
            until 22@ > 0
            0C78: set_timer 1 active false
            0C50: samp textdraw 10 set_string 'Use!'
        end
    end
   
    if 1@ < -1
    then
        0C78: set_timer 1 active false
        0C50: samp textdraw 10 set_string 'Use!'
        018C: play_sound 1057 at 0.0 0.0 0.0
        1@ = 0
    end
   
    if 8C79: not is_timer 1 active
    then 1@ = 0
    end
end

:TEXTDRAW_POS
23@ = SAMP.GetSAMPPlayerIDByActorHandle($PLAYER_ACTOR)
22@ = SAMP.GetPlayerHealthByActorHandle(23@)
0A8D: 11@ = read_memory 12030944 size 4 virtual_protect true
if 803B: not 11@ == 9@
then
    if 10@ == 1
    then
        0C51: samp textdraw 10 set_pos 610.0 76.0
        10@--
    else
        0C51: samp textdraw 10 set_pos 610.0 65.5
        10@++
    end
    0085: 9@ = 11@
end
return

:RPC_INCOMING
0BE5: raknet 30@ = get_hook_param PARAM_PACKETID
if 30@ == RPC_SCRCLIENTMESSAGE
then
    alloc 28@ 256
    alloc 27@ 20
    alloc 26@ 40
    0BE5: raknet 30@ = get_hook_param PARAM_BITSTREAM
    BitStream.IgnoreBits(30@, 32)
    29@ = BitStream.Read(30@, BS_TYPE_INT)
    BitStream.ReadArray(30@, 28@, 29@)
    0C1E: array 28@ element 29@ el_size 1 = 0x0
    27@ = SAMP.GetPlayerNickname(23@)
    format 26@ " %s употребил(a) наркотик" 27@
    if and
      0C14: strcmp string1 28@ string2 26@
      8C79: not is_timer 1 active
    then 31@++
    else
        0AD4: 25@ = scan_string 28@ format " (( Здоровье пополнено до: %i ))" 22@
        if 25@ == true
        then 31@++
        end
    end
    if 31@ == true
    then
        1@ = 60
        0C77: set_timer 1 interval 0
        0C78: set_timer 1 active true
        018C: play_sound 1052 at 0.0 0.0 0.0
        31@--
    end
    free 28@
    free 27@
    free 26@
end
0BE0: raknet hook_ret true

:CMD_SBIV
0B12: 8@ = 8@ XOR 1
0AF1: write_int 8@ to_ini_file 'CLEO\sbiv.ini' section "Drugtimer for Evolve RP" key 'sbiv'
if 8@ == true
then
    SAMP.ReadSAMPMemory(19@, 0x16FA0, 2)
    SAMP.WriteSAMPMemory(0x16FA0, 50064, 2)
    chatmsg "Сбив анимации {44DD44}включён" -1
else
    SAMP.WriteSAMPMemory(0x16FA0, 19@, 2)
    chatmsg "Сбив анимации {DD4444}выключен" -1
end
SAMP.CmdRet()

:CMD_RESET
if 0C79: is_timer 1 active
then
    0C78: set_timer 1 active false
    018C: play_sound 1057 at 0.0 0.0 0.0
    0C50: samp textdraw 10 set_string 'Use!'
    1@ = 0
end
SAMP.CmdRet()

:CMD_INFO
if not SAMP.IsDialogActive(619)
then
    0AC6: 0@ = label @INFO offset
    SAMP.ShowDialog(619, "Наркотаймер для {FF384F}Evolve RP", 0@, 'OK', '', DIALOG_STYLE_MSGBOX)
end
SAMP.CmdRet()

:INFO
hex
  "{FF384F}/tinfo\t{FFFFFF}Отобразить вспомогательный диалог\n"
  "{FF384F}/tsbiv\t{FFFFFF}Включить / выключить сбив\n"
  "{FF384F}/tres\t{FFFFFF}Обнулить таймер" 0
end

:TIMER
if 1@ == 60
then 0C77: set_timer 1 interval 1000
end
if 1@ >= 0
then
    format 24@s '%d' 1@
    0C50: samp textdraw 10 set_string 24@s
end
1@--
SAMP.CmdRet()